Clojurians Log v2

Hi folks, I created the library: https://github.com/dawran6/emoji. Currently the emoji.core ns is about 100 loc. Feel free to drop your comments here or on the Github issues. Thank you! 😄

What would be a better way of doing this?

(defn filter-trip
  [trip]
  (cond
   (= nil (:id trip)) false
   (= nil (:tripData trip)) false
   (= nil (:tenantId trip)) false
   (= nil (-> trip :tripData :startLocation)) false
   (= nil (-> trip :tripData :endLocation)) false
   (= nil (-> trip :tripData :segments)) false
   (= nil (:device trip)) false
   (= nil (-> trip :device :id)) false
   ((contains? #{"BAD" "UNUSABLE"} (:accuracy trip))) false
   :else trip))

I feel it's a bit clunky

@dharrigan Maybe this?

(defn legit-trip?
  [{{:keys [startLocation endLocation segments]} :tripData
    {:keys [id]} :device
    :as trip}]
  (and startLocation endLocation segments id
       (every? trip [:tenantId :id])
       (not (#{"BAD" "UNUSABLE"} (:accuracy trip)))))

Your fn seems to be a predicate

But if you want the trip to be returned in the truthy case (for use with keep maybe), then you can wrap the and expr in an if and return it.

nice, thank you - definitely looks sweeter 🙂

Both these versions return truthy even if :accuracy isn't present in trip. Is that intentional?

@dharrigan An alternative version, if the prev. one has too much destructuring for your taste 😄

(defn legit-trip?
  [trip]
  (and (not (some #(nil? (get-in trip %))
               [[:id]
                [:tenantId]
                [:device :id]
                [:tripData :startLocation]
                [:tripData :endLocation]
                [:tripData :segments]]))
       (not (#{"BAD" "UNUSABLE"} (:accuracy trip)))))

ah, that was an oversight, if accuracy is not present, it should be false

I always um and ah about destructuring in function arguments - sometimes I like, sometimes...not so sure 🙂

@dharrigan A little destructuring is probably best. Here's one with "a little" destructuring

(defn legit-trip?
  [{:keys [tripData device] :as trip}]
  (not (or (some #(nil? (% trip)) [:id :accuracy :tenantId])
           (some #(nil? (% tripData)) [:startLocation :endLocation :segments])
           (nil? (:id device))
           (#{"BAD" "UNUSABLE"} (:accuracy trip)))))

I'll stop tagging you now. Sorry if noise 😅

It's okay - really appreciate helpful feedback, I like to learn 🙂

Thanks and have a nice day!