Clojurians Log v2

So I may be off my rocker due to my naivate. I’m presently on a quest to combine the fulcro-native and fulcro-rad templates as I want the best of both worlds. My present challenge is trying to figure out the least hacky way to handle the bifurcation required for the /api call vs the /api-native call. Right now what’s seeming to me to be the nicest (please don’t judge me, I’m relatively new to all this still 🙂 ) way of doing it is to modify ring’s ‘wrap-defaults’ function so that it can take multiple configurations and simply apply what it presently does for the one configuration to each configuration. I’m a bit green to try and guess if there are any unwanted outcomes of attempting that. I’m also uncertain if there might not be some other way of going about it that would be as, or less, complex. Any suggestions? I’m frankly a bit trepidatious about tweaking a function in ring. Either maintaining a fork OR trying to propose a change gives me pause. I’m learning everyday, but frankly the capabilities of all my fellow clojurists intimidate me to no end (not because anyone is condescending or bad like that, just because they all seem frightfully competent and I’m never sure I’m up to snuff) Anywho. Anyone’s thoughts? Opinions? Snide remarks 😉 ? I reallly really really am in love with the idea of having RAD and native together. It tickles me something fierce. But wow is it taking me longer than I was hoping it would.

@vaedasynapse I'm not sure what problems you foresee. Are the queries and mutations from your native endpoint different? I don't think you will need two endpoints. If there are details that differ between native and web you have several ways to handle that, e.g. change the request (think query params/namespaced keys/namespaced mutations) or write ring middleware to inject the information based on a header or so. Don't be afraid of ring, the whole point of ring is to write your own middleware functions and enrich the request handling like that. RAD on the back-end mostly just generates auto resolvers for your parser and that probably stays the same between web and native.

How do I apply an fs/mark-complete! to an entire form? I tried using it like (fs/mark-complete!) but that didn't work. And neither did (fs/mark-complete! {:entity-ident [:component/id ::TheComponentName]})

@vaedasynapse I assume you’re speaking of auth? (since everything else simply depends on a ui plugin for native). So yes, that need a small bit of work since you don’t have cookies on a phone. What I’ve done is what you are saying: make an /api-native…but I use the exact same everything in that chain except auth. There is no api difference.

In one of our apps we only use websockets on a particular mobile app, and there will definitely be cookies when the webapp uses websockets:

(defn mobile?
  "A request is mobile if

  1. The URI is /mobile-api OR
  2. The request has NO cookies AND is for websockets /chsk."
  [{:keys [uri headers] :as req}]
  ;; WARNING: Cookies have not been decoded yet, so you have to use raw headers
  (let [cookie (get headers "cookie")]
    (or
      (= "/mobile-api" uri)
      (and (= "/chsk" uri) (nil? cookie)))))

(defstate middleware
  :start
  (let [defaults-config (:ring.middleware/defaults-config s.config/config)]
    (-> not-found-handler
      wrap-websockets
      (wrap-api "/api")
      (wrap-api "/mobile-api")
      (file-upload/wrap-mutation-file-uploads {})
      (wrap-file-response)
      (server/wrap-transit-params {:opts {:handlers (:read transit-handlers)}})
      (server/wrap-transit-response {:opts {:handlers (:write transit-handlers)}})
      (wrap-html5-routes)
      (blob/wrap-blob-service "/rad-files" s.rad-storage/file-store)
      (wrap-if mobile?
        #(wrap-mobile-defaults % defaults-config)
        #(wrap-browser-defaults % defaults-config)))))

where wrap-if is:

(defn wrap-if
  "Create a fork in the middleware. If the incoming request-predicate is true, then continue through then-wrapper, else else-wrapper"
  [handler request-predicate then-wrapper else-wrapper]
  (let [then-middleware (then-wrapper handler)
        else-middleware (else-wrapper handler)]
    (fn [req]
      (if (request-predicate req)
        (then-middleware req)
        (else-middleware req)))))

(I was pretty delighted with wrap-if , though I’m sure others have thought of it as well)

yeah, should have done google search 🙂 (https://github.com/pjlegato/ring.middleware.conditional)…well, it was simple and fun to write anyway

and then the only thing left is to toggle the stuff in the branches:

(defn wrap-mobile-defaults
  "Mobile defaults:

  * Turn off ring CSRF and Cookie backed sessions.
  * Use a different session store for our mobile session-key.
  * Hard-reject any session-key with the wrong prefix."
  [handler config]
  (let [wrap-mobile-session (fn [handler]
                              (fn [req]
                                (handler (session-store/ensure-mobile-session-key req))))]
    (-> handler
      (wrap-mobile-session)
      (wrap-reject-web-session)
      (wrap-defaults (-> config
                       (update :security dissoc :anti-forgery)
                       (dissoc :session))))))

for mobile we just send back a special customer header with a token, which the mobile app looks for and stores in SecureStore

So, on the mobile client, we modify the http remote middleware like so:

(defn wrap-auth [handler]
  (fn [req]
    (let [session-key (auth/session-key-local-storage)]
      (handler (update req :headers assoc "fsi-authorization" session-key)))))

(def request-middleware
  (-> identity
    (net/wrap-fulcro-request (:write transit-handlers))
    (wrap-auth)))

...

(def fulcro-remote (net/fulcro-http-remote
                                          {:url                 m.app-util/server-url
                                           :response-middleware m.app-util/response-middleware
                                           :request-middleware  m.app-util/request-middleware}))

This is what I was referring to, this is awesome. Thanks so much! Much better than what I was thinking to do. Thanks Tony and bbss!