Clojurians Log v2

hi, I have a question related to in place transformation, I'll try to explain it with an example. I have this data:

{:records  [{:name "A" :value 1 :foo "not-important"} 
	        {:name "B" :value 2 :bar "not-important"}]}

{:records  [{:name "A" :value 0} 
	        {:name "B" :value 2}]}

(m/rewrite records
   {:records [{:name !name :value !value} ...]}
   {:records [{:name !name :value !value} ...]})

you probably need a record-transforming function, and then use m/app to call it in the RHS of the rewrite rule

`(m/rewrite data {:records [!r ...]} {:records [(m/app transform-record !r) ...]})`

or maybe abuse m/cata to match on both the overall shape and each record with the same rule

@jlle Here is one way to do that in meander directly. Inline:

(m/rewrite {:records  [{:name "A" :value 1 :foo "not-important"} 
	               {:name "B" :value 2 :bar "not-important"}]}

  {:records  [(m/or (m/let [!value 0] {:name (m/and "A" !name)})
                    {:name !name :value !value}) ...]}
  {:records [{:name !name :value !value} ...]})

(m/rewrite {:records  [{:name "A" :value 1 :foo "not-important"} 
	               {:name "B" :value 2 :bar "not-important"}]}

  (m/with [%record (m/or (m/let [!value 0]
                           {:name (m/and "A" !name)})
                         
                         {:name !name :value !value})]
    
    {:records [%record ...]})
  {:records [{:name !name :value !value} ...]})

And since @qythium mentioned cata. Here is the cata way of doing it

(m/rewrite {:records [{:name "A" :value 1 :foo "not-important"} 
	                  {:name "B" :value 2 :bar "not-important"}]}

  {:records [(m/cata !record) ...]}
  {:records [!record ...]}

  {:name (m/and "A" ?name)} {:name ?name :value 0}

  {:name ?name :value ?value} {:name ?name :value ?value})

I don’t think I’d call this an abuse. Actually reads fairly well. The biggest thing to watch out for is order. {:name ?name :value ?value} will match any map, even if it doesn’t have :name as a key (it will assign nil to ?name`) . So it needs to be at the end, or constrained with a m/some.

heh, I called it an "abuse" because the structure didn't seem like it was recursive in the same way as eg. syntax trees or hiccup vectors that called for a catamorphism

Yeah that is true. The cata will continue to recurse if there is another :records entry.

using with in that above code to extract a sub-pattern is a nice motivating example for the syntax though, I've personally been scared off by "yet another %prefix" to really look into it

Finally (and yes I know this is information overload), there is really no reason you can’t just pull things out into a function.

(defn transform-record [record]
  (m/rewrite record
    {:name (m/and "A" ?name)} {:name ?name :value 0}
    {:name ?name :value ?value} {:name ?name :value ?value}))


(m/rewrite {:records [{:name "A" :value 1 :foo "not-important"} 
	                  {:name "B" :value 2 :bar "not-important"}]}

  {:records [(m/app transform-record !record) ...]}

  {:records [!record ...]})